Processing:キネマティックボディで物体を引っ張る - 元Webデザイナー兼コーダーの備忘録

「The Nature of Code」からキネマティックボディについて取り上げます。ボディのタイプをキネマティックにして、物体を引っ張ってみます。Processingでプログラムを書いて、動作を確認します。動作を確認できるところがProcessingの楽しいところです。

キネマティックボディ
まとめ
参考書籍

キネマティックボディ

マウスジョイントを使って物体をドラッグしていましたが、ボディのタイプをキネマティックにすることでも実現できます。

以下は、その参考例です。

注意としてキネマティックボディは、キネマティックまたはスタティックなボディと衝突しません。衝突させたい場合は、マウスジョイントが適しています。

//Basic example of controlling an object with the mouse (by attaching a spring)
import shiffman.box2d.*;
import org.jbox2d.common.*;
import org.jbox2d.dynamics.joints.*;
import org.jbox2d.collision.shapes.*;
import org.jbox2d.collision.shapes.Shape;
import org.jbox2d.dynamics.*;

Box2DProcessing box2d;
ArrayList<Boundary> boundaries;
Box box;

void setup(){
  size(640, 360);
  
  box2d = new Box2DProcessing(this);
  box2d.createWorld();
  
  box = new Box(width/2, height/2);
  
  //境界
  boundaries = new ArrayList();
  boundaries.add(new Boundary(width/2, height-5, width, 10, 0));
  boundaries.add(new Boundary(width/2, 5, width, 10, 0));
  boundaries.add(new Boundary(width-5, height/2, 10, height, 0));
  boundaries.add(new Boundary(5, height/2, 10, height, 0));
}

void draw(){
  background(255);
  box2d.step();
  
  if(box.dragged){
    box.setPosition(mouseX, mouseY);
  }
  
  for(Boundary wall: boundaries){
    wall.display();
  }
  
  box.display();
}

//マウスを押したときの処理
void mousePressed(){
  if(box.contains(mouseX, mouseY)){
    box.dragged = true;
  }
}

//マウスを離したときの処理
void mouseReleased(){
    box.dragged = false;
}

class Boundary{
  float x;
  float y;
  float w;
  float h;
  Body body;
  
  //コンストラクタ
  Boundary(float x_, float y_, float w_, float h_, float a){
    x = x_;
    y = y_;
    w = w_;
    h = h_;
    
    //ボディの定義
    BodyDef bd = new BodyDef();
    bd.type = BodyType.STATIC;
    bd.angle = a;
    bd.position.set(box2d.coordPixelsToWorld(x, y));
    body = box2d.createBody(bd);
    
    //シェイプの定義
    PolygonShape sd = new PolygonShape();
    float box2dW = box2d.scalarPixelsToWorld(w/2);
    float box2dH = box2d.scalarPixelsToWorld(h/2);
    sd.setAsBox(box2dW, box2dH);
    
    body.createFixture(sd,1);
  }
  
  //図形の描画
  void display(){
    noFill();
    stroke(0);
    strokeWeight(1);
    rectMode(CENTER);
    
    float a = body.getAngle();
    
    pushMatrix();
    translate(x, y);
    rotate(-a);
    rect(0, 0, w, h);
    popMatrix();
  }
}

class Box{
  Body body;
  float w;
  float h;
  boolean dragged = false;
  //コンストラクタ
  Box(float x_, float y_){
    float x = x_;
    float y = y_;
    w = 24;
    h = 24;
    
    makeBody(new Vec2(x, y), w, h);
  }
  
  //マウス座標がオブジェクト内にあるかの判定
  boolean contains(float x, float y){
    Vec2 worldPoint = box2d.coordPixelsToWorld(x, y);
    Fixture f = body.getFixtureList();
    boolean inside = f.testPoint(worldPoint);
    return inside;
  }
  
  void setAngularVelocity(float a){
    body.setAngularVelocity(a);
  }
  
  void setVelocity(Vec2 v){
    body.setLinearVelocity(v);
  }
  
  void setPosition(float x, float y){
    Vec2 pos = body.getWorldCenter();
    Vec2 target = box2d.coordPixelsToWorld(x, y);
    Vec2 diff = target.sub(pos);
    diff.mulLocal(50);
    setVelocity(diff);
    setAngularVelocity(0);
  }
  
  //図形の描画
  void display(){
    Vec2 pos = box2d.getBodyPixelCoord(body);
    float a = body.getAngle();
    
    rectMode(PConstants.CENTER);
    pushMatrix();
    translate(pos.x, pos.y);
    rotate(-a);
    fill(175);
    stroke(0);
    rect(0, 0, w, h);
    popMatrix();
  }
  
  //Box2Dの設定
  void makeBody(Vec2 center, float w_, float h_){
    //ボディの定義
    BodyDef bd = new BodyDef();
    bd.type = BodyType.KINEMATIC;  //キネマティック
    bd.position.set(box2d.coordPixelsToWorld(center));
    body = box2d.createBody(bd);
    
    //シェイプの定義
    PolygonShape sd = new PolygonShape();
    float box2dW = box2d.scalarPixelsToWorld(w_/2);
    float box2dH = box2d.scalarPixelsToWorld(h_/2);
    sd.setAsBox(box2dW, box2dH);
    
    //フィクスチャの定義
    FixtureDef fd = new FixtureDef();
    fd.shape = sd;
    //物理パラメータの設定
    fd.density = 1;
    fd.friction = 0.3;
    fd.restitution = 0.5;
    
    body.createFixture(fd);
    
    body.setLinearVelocity(new Vec2(random(-5, 5), random(2, 5)));
    body.setAngularVelocity(random(-5, 5));
  }
}